hier ist die software sie kam auf einen cd vom hersteller :

;************************************************* **********
;* Examples Program For "CP-JRAVR (TINY2313) *
;* Target MCU : Atmel ATTINY2313 *
;* Frequency : X-TAL : 8 MHz *
;* Compiler : AVR Studio 4.12 (AVR Assembler 2) *
;* Last Update : 28/June/2006 *
;* Description : Example Use Character LCD 16x2 4-bit *
;************************************************* **********

.include "tn2313def.inc"

.ORG $0000
RJMP RESET_VEC ;Reset Handle

.EQU PORT_LCD = PORTB
.EQU DDR_LCD = DDRB
.EQU BIT_RS = 2
.EQU BIT_CS = 3

.DEF TEMP = R19
.DEF TEMP1 = R20

RESET_VEC: LDI TEMP,LOW(RAMEND)
OUT SPL,TEMP ;init Stack Pointer Low
LDI TEMP,HIGH(RAMEND)
OUT SPL+1,TEMP ;init Stack Pointer High

RCALL DELAY ;delay for start

LDI TEMP,0XFC
OUT DDR_LCD,TEMP

SBI PORT_LCD,BIT_RS
SBI PORT_LCD,BIT_CS

RCALL INIT_LCD ;initial LCD

LDI ZL,LOW(TEXT_TAB*2)
LDI ZH,HIGH(TEXT_TAB*2)
LOOP: LPM
TST R0
BREQ WAIT
MOV TEMP,R0
RCALL WR_LCD
ADIW ZL,0X01
RJMP LOOP

WAIT: RJMP WAIT

;************************************************* ***
;* SUBRUTINE FOR WRITE DATA TO LCD *
;************************************************* ***
WR_LCD: PUSH TEMP
ANDI TEMP,0XF0
SBI PORT_LCD,BIT_RS
IN TEMP1,PORT_LCD
ANDI TEMP1,0X0F
OR TEMP,TEMP1
OUT PORT_LCD,TEMP
RCALL EN_LCD
POP TEMP
SWAP TEMP
ANDI TEMP,0XF0
IN TEMP1,PORT_LCD
ANDI TEMP1,0X0F
OR TEMP,TEMP1
OUT PORT_LCD,TEMP
RCALL EN_LCD
RET
;************************************************* ***
;* WRITE INSTRUCTION LCD *
;*INPUT:TEMP *
;************************************************* ***
WR_INS: PUSH TEMP
ANDI TEMP,0XF0
CBI PORT_LCD,BIT_RS
IN TEMP1,PORT_LCD
ANDI TEMP1,0X0F
OR TEMP,TEMP1
OUT PORT_LCD,TEMP
RCALL EN_LCD
POP TEMP
SWAP TEMP
ANDI TEMP,0XF0
IN TEMP1,PORT_LCD
ANDI TEMP1,0X0F
OR TEMP,TEMP1
OUT PORT_LCD,TEMP
RCALL EN_LCD
RET
;************************************************* **
;* initial LCD *
;*INPUT: TEMP *
;************************************************* **
INIT_LCD: LDI TEMP,0X33
RCALL WR_INS
LDI TEMP,0X32
RCALL WR_INS
LDI TEMP,0X28
RCALL WR_INS
LDI TEMP,0X0C
RCALL WR_INS
LDI TEMP,0X06
RCALL WR_INS
LDI TEMP,0X01
RCALL WR_INS
RET
;************************************************* ***
;* ENABLE LCD *
;************************************************* ***
EN_LCD: CBI PORT_LCD,BIT_CS
RCALL BUSY
SBI PORT_LCD,BIT_CS
RET

;************************************************* ***
;* DELAY TIME FOR BUSY *
;************************************************* ***
BUSY: PUSH R26
PUSH R27
LDI R27,0X10
BUSY2: LDI R26,0XFF
BUSY1: DEC R26
BRNE BUSY1
DEC R27
BRNE BUSY2
POP R27
POP R26
RET
;************************************************* **
;* DELAY TIME FOR START *
;************************************************* **
DELAY: PUSH R26
PUSH R27
LDI R27,0XFF
DEL2: LDI R26,0XFF
DEL1: DEC R26
BRNE DEL1
DEC R27
BRNE DEL2
POP R27
POP R26
RET

TEXT_TAB: .DB "CP-JRAVR V1.0",0X00



ich habe aber die hex file programiert