Sonnenbahnberechnung mit BASCOM

[dolivo]

Hallo,
ich habe nach http://lexikon.astronomie.info/zeitgleichung/ ein BASCOM-Programm geschrieben, das allerdings noch nicht ausführlich getestet ist. Als Zeitgeber soll eine DCF-Uhr dienen.

'Sonnentest 13.4.12
'lexikon.astronomie.info/zeitgleichung/
'für Radebeul: 13°37' Ost, 51°06' Nord

$crystal = 1000000
$regfile = "m48def.dat"

$hwstack = 32                 ' default use 32 for the hardware stack
$swstack = 10                 ' default use 10 for the SW stack
$framesize = 40

Dim Woz_moz As Single , Term1 As Single , Term2 As Single , Term3 As Single
Dim Deklination As Single , Zeitdiff As Single , Sa As Single , Su As Single
Dim Samin As Single , Sumin As Single
Dim Tag As Integer , Diff2 As Integer
Dim Sahour As Byte , Samin1 As Byte , Suhour As Byte , Sumin1 As Byte
Dim Sastrmin As String * 3 , Sustrmin As String * 3

Anfang:
 Input "Tagzahl " , Tag

 Term1 = 0.0337 * Tag         'Berechnung Differenz Wahre + Mittlere
 Term1 = Term1 + 0.465        'Ortszeit
 Term1 = Sin(term1)
 Term1 = -0.171 * Term1

 Term2 = 0.01787 * Tag
 Term2 = Term2 - 0.168
 Term2 = Sin(term2)
 Term2 = 0.1299 * Term2

 Woz_moz = Term1 - Term2      'Zeitgleichung /in Stunden
 Diff2 = Woz_moz * 60         'auf Minuten gerechnet

 Term1 = Tag - 80.086         'Berechnung Deklination
 Term1 = Term1 * 0.016906
 Term1 = Sin(term1)
 Deklination = Term1 * 0.4095

 Term1 = Sin(deklination)     'Berechnung Zeitdifferenz
 Term1 = 0.7771 * Term1       'B=0,89 für Radebeul
 Term1 = -0.0145 - Term1
 Term2 = Cos(deklination)
 Term2 = 0.6294 * Term2
 Zeitdiff = Term1 / Term2
 Zeitdiff = Acos(zeitdiff)
 Zeitdiff = 3.8197 * Zeitdiff

 Sa = 12 - Zeitdiff           'Sonnenaufgang
 Sa = Sa - Woz_moz
 Sa = Sa - 0.9067
 Sa = Sa + 1                  'MEZ, bei MESZ +2
 Samin = Frac(sa)
 Sahour = Sa - Samin
 Samin1 = Samin * 60
 Sastrmin = Str(samin1)
 Sastrmin = Format(sastrmin , "00")

 Su = 12 + Zeitdiff
 Su = Su - Woz_moz
 Su = Su - 0.9067
 Su = Su + 1
 Sumin = Frac(su)
 Suhour = Su - Sumin
 Sumin1 = Sumin * 60
 Sustrmin = Str(sumin1)
 Sustrmin = Format(sustrmin , "00")


 Print "WOZ-MOZ: " ; Woz_moz
 Print "min: " ; Diff2
 Print "Deklination: " ; Deklination
 Print "Zeitdifferenz: " ; Zeitdiff
 Print "Sonnenaufgang: " ; Sahour ; ":" ; Sastrmin
 Print "Sonnenuntergang: " ; Suhour ; ":" ; Sustrmin
 Print
 Goto Anfang

 End