Hallo Corone,
nimm einfach irgendein Prog für den RP5 und füge das hier ein, wenn du das LCD richtig angeschlossen hast.
Evtl. must du Variablen ändern.
Gruß Dirk
Code:
'------ LCD INTERFACE ------
define lcd_port byteport[2] 'Frei, wenn kein LCD angeschlossen ist!
define lcd_rs port[14]
define lcd_rw port[13]
define lcd_e port[15]
'---- LCD DRIVER -------------
define lcd_buf byte[7] 'Bytes 7 und 8 frei, wenn LCD nicht genutzt wird!
define lcd_param byte[8]
' LC-Display initialisieren:
gosub LCD_INIT
pause 1
gosub LCD_CLS
lcd_param = &H54 : gosub lcd_writechar 'T
lcd_param = &H45 : gosub lcd_writechar 'E
lcd_param = &H53 : gosub lcd_writechar 'S
lcd_param = &H54 : gosub lcd_writechar 'T
end
'----------------------------------------
'------------- LCD ROUTINES -------------
'----------------------------------------
#LCD_INIT
' alle ports 0
lcd_port = OFF
' 8-Bit-Modus aktivieren
lcd_param=&H38 : gosub LCD_WRITECMD
' mit 8-Bit-Command in 4-Bit-Modus umschalten
lcd_port=&B00000010
tog lcd_e
tog lcd_e
' ab jetzt 4-Bit-Modus
lcd_param = &H28 : gosub LCD_WRITECMD
lcd_param = &H0C : gosub LCD_WRITECMD
' Display loeschen
#LCD_CLS
lcd_param = &H02 : gosub LCD_WRITECMD
lcd_param = &H01 : gosub LCD_WRITECMD
return
' Zeilenwechsel
#LCD_GOTOLINE
if lcd_param = 1 then lcd_param = &H80
if lcd_param = 2 then lcd_param = &HC0
goto LCD_WRITECMD
' LCD-Kommando
#LCD_WRITECMD
lcd_buf = OFF
goto LCD_WRITE
' Zeichenausgabe
#LCD_WRITECHAR
lcd_buf = &B00100000
' Kommando oder Zeichen an Display senden
#LCD_WRITE
lcd_port = lcd_buf or (lcd_param shr 4) ' Hi-Nibble
tog lcd_e
tog lcd_e
lcd_port = lcd_buf or (lcd_param and &H0F) ' Lo-Nibble
tog lcd_e
tog lcd_e
return
Lesezeichen